Excel中八大經(jīng)典函數(shù)組合，幫你整理齊了！
Excel中八大經(jīng)典函數(shù)組合，幫你整理齊了！
excelpx-tete
每天一篇excel原創(chuàng)教程，由淺入深，全面學(xué)習(xí)excel技巧、函數(shù)、圖表和VBA編程。有excel問(wèn)題也可以提問(wèn)哦！
在Excel公式中，有些函數(shù)是獨(dú)行俠，而有些函數(shù)經(jīng)常是成對(duì)出現(xiàn)的，今天蘭色就帶大家一起盤點(diǎn)Excel表格中八大經(jīng)典函數(shù)組合。
1、 IF + And
作用：并列多條件判斷
【例】如下圖所示，在C列設(shè)置公式，如果A列值 小于500 且B列值為 未到期 ，則返回”補(bǔ)款“，否則顯示為空。
公式：C2
= IF ( AND (A2<500,B2="未到期"),"補(bǔ)款","")
說(shuō)明：兩個(gè)條件同時(shí)成立用AND,任一個(gè)成立用OR函數(shù)。
2、 Index + Match
作用：根據(jù)條件查詢
【例2】如下圖所示，要求根據(jù)月份和費(fèi)用項(xiàng)目，查找金額
E10公式：
= INDEX ( B2:G6, MATCH (B10,$A$2:$A$6,0), MATCH (A10,$B$1:$G$1,0) )
公式說(shuō)明：
先用MATCH函數(shù)查找3月在第一行中的位置
= MATCH (B10,$A$2:$A$6,0)
再用MATCH函數(shù)查找費(fèi)用項(xiàng)目在A列的位置
= MATCH (A10,$B$1:$G$1,0)
最后用INDEX根據(jù)行數(shù)和列數(shù)提取數(shù)值
= INDEX(區(qū)域,行數(shù),列數(shù)）
3、 Iferror + Vlookup
作用：當(dāng)Vlookup查找不到時(shí)屏蔽查錯(cuò)誤值
【例】如下圖所示，要求根據(jù)產(chǎn)品名稱在上表中查找單價(jià)，如果產(chǎn)品不存在則顯示為空白
B9公式：
= IFERROR ( VLOOKUP (A8,$A$1:$D$5,3,0) , "" )
4、 Mid + Find
作用：根據(jù)條件截取字符串
【例】在個(gè)人信里截取出年齡
B2公式
= MID (A2, FIND (" ",A2)+1,9)
注：find查找分隔符的位置，MID負(fù)責(zé)截取字符
5、 Left + lenB + Len
作用：分離漢字、數(shù)字和字母
示例：
= LEFT (A2, LENB (A2)- LEN (A2))
注：帶B的函數(shù)是按字節(jié)計(jì)數(shù)，而一個(gè)漢字占2個(gè)字節(jié)，數(shù)字和字母則占1個(gè)。所以用 LENB(A2)-LEN(A2)可以倒推出漢字的個(gè)數(shù)，然后用left或mid函數(shù)截取。
6、 index + Small + Row
作用：一對(duì)多查找
【例】如下圖所示，要求在F列查找“張明城”的個(gè)人消費(fèi)記錄
F2公式
{= INDEX (C:C, SMALL (IF(B$2:B$10=F$1, ROW ($2:$10)),ROW(A1)))}
公式解析：
-
IF(B$2:B$10=F$1,ROW($2:$10)) ： 如果B列的姓名和F1的姓名相同，就返回它的行號(hào)。不相同的返回FALSE
-
Row(a1) ：是返回A1的行號(hào)1，如果向下復(fù)制會(huì)變?yōu)?Row(a2)，返回2，其實(shí)用它的目的是當(dāng)公式向下復(fù)制時(shí)可以生成序號(hào)：1，2，3...然后取符合條件的第1個(gè)行號(hào)，第2個(gè)行號(hào)...
-
SMALL() : 從符合條件的行號(hào)中從小到大，逐個(gè)提取符合條件的行
-
INDEX() :根據(jù)取得的行號(hào)從C列提取值
-
{ } ：數(shù)組公式（含有逐一運(yùn)算的公式）需要按ctrl+shift+enter 輸入大括號(hào)（一定要是自動(dòng)生成的，不能手輸入大括號(hào)）。
7、 Sum + Offset + Count
作用：最后N天求和
【例】在D2單元格返回B列最近7天的銷量
D2公式：
= SUM ( OFFSET (B1, COUNTA(B:B) -7,0,7,1))
注：Counta負(fù)責(zé)統(tǒng)計(jì)B列非空值個(gè)數(shù)，offset負(fù)責(zé)生成動(dòng)態(tài)最后N天區(qū)域，SUM負(fù)責(zé)求和
8、 Sumproduct + Countif
作用：計(jì)算不重復(fù)值個(gè)數(shù)
【例】：統(tǒng)計(jì)B列的客戶數(shù)量
= SUMPRODUCT (1/ COUNTIF (B2:B19,B2:B19))
注：Countif函數(shù)統(tǒng)計(jì)出每個(gè)客戶的出現(xiàn)次數(shù)，Sumprodcut對(duì) 1/出現(xiàn)次數(shù) 進(jìn)行求和。每個(gè)客戶無(wú)論出現(xiàn)多少次，求和的結(jié)果都是1，求和后正好是不重復(fù)個(gè)數(shù)。
蘭色說(shuō) ：Excel公式中的函數(shù)嵌套對(duì)新手是一個(gè)難點(diǎn)，所以掌握這些固定套路尤為重要。
長(zhǎng)按 下面二維碼圖片，點(diǎn)上面 ” 前往圖中包含的公眾號(hào) “ 然后再點(diǎn)關(guān)注，每天可以收到一篇蘭色最新寫的excel教程。